home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Grab Bag
/
Shareware Grab Bag.iso
/
015
/
fxfonts.bas
< prev
next >
Wrap
BASIC Source File
|
1987-01-03
|
6KB
|
146 lines
10 REM THIS PROGRAM SETS PRINTER FEATURES ON THE RX-80
20 REM BY JACK MALUSKY, CBI 10/4/83 (MOD. 8/3/84) ** MS/DOS VERSION
30 PRINT : PRINT : PRINT
40 DIM A!(30) : I=1! : LPRINT CHR$(27);"@";
50 DIM OP$(30) : DIM N$(30) : X$=" "
60 FOR J=1 TO 30
70 N$(J)="OFF" : NEXT J
80 N$(2)="ON"
90 OP$(1)="1. ELITE SIZE PRINT"
100 OP$(2)="2. PICA SIZE PRINT"
110 OP$(3)="3. DOUBLE-WIDE"
120 OP$(4)="4. CONDENSED PRINT"
130 OP$(5)="5. EMPHASIZED MODE"
140 OP$(6)="6. DOUBLE-STRIKE"
150 OP$(7)="7. SUPER-SCRIPT MODE"
160 OP$(8)="8. SUB-SCRIPT MODE"
170 OP$(9)="9. UNDER-LINE"
180 OP$(10)="10.SET HALF SPEED "
190 OP$(11)="11.BI/UNI DIRECTIONAL"
200 OP$(12)="12.RING PRINT BUZZER"
210 OP$(13)="13.TOGGLE 6/8 LPI "
220 OP$(14)="14.USA CHAR SET "
230 OP$(15)="15.FRANCE CHAR SET"
240 OP$(16)="16.GERMAN CHAR SET"
250 OP$(17)="17.U.K. CHAR SET "
260 OP$(18)="18.DENMARK CHAR SET"
270 OP$(19)="19.SWEDEN CHAR SET"
280 OP$(20)="20.ITALIAN CHAR SET"
290 OP$(21)="21.SPAIN CHAR SET "
300 OP$(22)="22.JAPAN CHAR SET "
310 OP$(23)="23.NORWAY CHAR SET"
320 OP$(24)="24.DENMARK 2 CHAR SET"
330 OP$(25)="25.GRAPHICS CHARS "
340 OP$(26)="26.SET ITALICS "
350 OP$(27)="27.BABY FACE FONT "
360 OP$(28)="28. "
370 OP$(29)="29.RESET ALL SETTINGS"
380 OP$(30)="30.PRINT TEST LINE"
390 LPRINT CHR$(27);"@"; : REM INITIALIZE PRINTER
400 PRINT : PRINT TAB(15)"PRINTER OPTION SELECTION MENU"
410 PRINT TAB(15)" by Jack Malusky"
420 PRINT : PRINT
430 FOR J=1 TO 15
440 PRINT OP$(J);TAB(25);N$(J);TAB(35);OP$(J+15);TAB(57);N$(J+15): NEXT J
450 PRINT:PRINT TAB(16);"SELECT OPTIONS BY NUMBER -- 0 TO END" : PRINT
460 INPUT A! : IF A!=0 OR A!>30 THEN GOTO 1450
470 IF N$(A!)="OFF" THEN N$(A!)="ON" : GOTO 490
480 N$(A!)="OFF" : GOTO 490
490 ON A! GOSUB 510,540,570,600,620,650,690,730,770,800,830,860,880,910,940,970,1000,1030,1060,1090,1120,1150,1180,1210,1240,1290,1320,1290,1360,1400
500 GOTO 400
510 REM ELITE
520 IF N$(2)="ON" THEN N$(2)="OFF"
530 LPRINT CHR$(27);"M"; : RETURN
540 REM PICA
550 IF N$(1)="ON" THEN N$(1)="OFF"
560 LPRINT CHR$(27);"P"; : RETURN
570 REM DOUBLE-WIDE
580 IF N$(3)="ON" THEN LPRINT CHR$(27);"W";CHR$(1); : RETURN
590 LPRINT CHR$(27);"W";CHR$(0); : RETURN
600 REM CONDENSED
610 IF N$(4)="ON" THEN LPRINT CHR$(15); ELSE LPRINT CHR$(18); : RETURN
620 REM EMPHASIZED
630 IF N$(5)="ON" THEN LPRINT CHR$(27)"E"; : RETURN
640 IF N$(5)="OFF" THEN LPRINT CHR$(27)"F"; : RETURN
650 REM DOUBLESTRIKE
660 IF N$(6)="ON" THEN LPRINT CHR$(27);"G"; : RETURN
670 IF N$(6)="OFF" THEN LPRINT CHR$(27);"H";: RETURN
680 LPRINT CHR$(27);"G"; : RETURN
690 REM SUPER-SCRIPT
700 IF N$(7)="OFF" THEN LPRINT CHR$(27);"T"; : RETURN
710 IF N$(8)="ON" AND N$(7)="OFF" THEN N$(8)="OFF" : N$(7)="ON"
720 LPRINT CHR$(27);"S";CHR$(0); : RETURN
730 REM SUB-SCRIPT
740 IF N$(8)="OFF" THEN LPRINT CHR$(27);"T"; : RETURN
750 IF N$(7)="ON" AND N$(8)="OFF" THEN N$(7)="OFF" : N$(8)="ON"
760 LPRINT CHR$(27);"S";CHR$(1); : RETURN
770 REM UNDER-LINE MODE
780 IF N$(9)="OFF" THEN LPRINT CHR$(27);"-";CHR$(0); : RETURN
790 LPRINT CHR$(27);"-";CHR$(1); : RETURN
800 REM #10 HALF SPEED PRINTING
810 IF N$(10)="ON" THEN LPRINT CHR$(27);"s";CHR$(1); :RETURN
820 IF N$(10)="OFF" THEN LPRINT CHR$(27);"s";CHR$(0); : RETURN
830 REM #11 SET BI OR UNI DIRECTIONAL PRINTING
840 IF N$(11)="ON" THEN LPRINT CHR$(27);"U";CHR$(1); : RETURN
850 IF N$(11)="OFF" THEN LPRINT CHR$(27);"U";CHR$(0); : RETURN
860 REM #12 RING BUZZER ON PRINTER
870 LPRINT CHR$(7); : RETURN
880 REM #13 TOGGLE BETWEEN 6/8 LINES PER INCH PRINTING
890 IF N$(13)="OFF" THEN LPRINT CHR$(27);"2"; : RETURN
900 IF N$(13)="ON" THEN LPRINT CHR$(27);"0"; : RETURN
910 REM #14 USA CHAR SET
920 LPRINT CHR$(27)"R"CHR$(0); : FOR J=33 TO 126
930 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(14): GOSUB 1400 : RETURN
940 REM #15 FRANCE CHAR SET
950 LPRINT CHR$(27);"R";CHR$(1); : FOR J=33 TO 126
960 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(15): GOSUB 1400 : RETURN
970 REM #16 GERMANY CHAR SET
980 LPRINT CHR$(27);"R";CHR$(2); : FOR J=33 TO 126
990 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(16): GOSUB 1400 : RETURN
1000 REM #17 U.K. CHAR SET
1010 LPRINT CHR$(27);"R";CHR$(3); : FOR J=33 TO 126
1020 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(17): GOSUB 1400 : RETURN
1030 REM #18 DENMARK CHAR SET
1040 LPRINT CHR$(27);"R";CHR$(4); : FOR J=33 TO 126
1050 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(18): GOSUB 1400 : RETURN
1060 REM #19 SWEDEN CHAR SET
1070 LPRINT CHR$(27);"R";CHR$(5); : FOR J=33 TO 126
1080 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(19): GOSUB 1400 : RETURN
1090 REM #20 ITALIAN CHAR SET
1100 LPRINT CHR$(27);"R";CHR$(6); : FOR J=33 TO 126
1110 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(20): GOSUB 1400 : RETURN
1120 REM #21 SPAIN CHAR SET
1130 LPRINT CHR$(27);"R";CHR$(7); : FOR J=33 TO 126
1140 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(21): GOSUB 1400 : RETURN
1150 REM #22 JAPAN CHAR SET
1160 LPRINT CHR$(27);"R";CHR$(8); : FOR J=33 TO 126
1170 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(22) : GOSUB 1400 : RETURN
1180 REM #23 NORWAY CHAR SET
1190 LPRINT CHR$(27);"R";CHR$(9); : FOR J=33 TO 126
1200 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(23): GOSUB 1400 : RETURN
1210 REM #24 DENMARK CHAR SET #2
1220 LPRINT CHR$(27);"R";CHR$(10); : FOR J=33 TO 126
1230 LPRINT CHR$(J); : NEXT J : LPRINT X$;OP$(24): GOSUB 1400 : RETURN
1240 REM #25 PRINT GRAPHICS CHARS
1250 LPRINT CHR$(27);"m";CHR$(4);
1260 FOR J=128 TO 159
1270 LPRINT CHR$(J);" "; : NEXT J : LPRINT : GOSUB 1400
1280 LPRINT CHR$(27);"m";CHR$(0); : RETURN
1290 REM #26 SET ITALICS
1300 IF N$(26)="ON" THEN LPRINT CHR$(27);"4"; : RETURN
1310 IF N$(26)="OFF" THEN LPRINT CHR$(27);"5"; : RETURN
1320 REM #27 BABY-FACE FONT
1330 IF N$(27)="ON" THEN LPRINT CHR$(15)CHR$(27)CHR$(83)CHR$(1)CHR$(27)CHR$(65)CHR$(6); : RETURN
1340 IF N$(27)="OFF" THEN LPRINT CHR$(27);"@"; : RETURN
1350 REM #28
1360 REM #29 RESET ALL SETTINGS
1370 FOR J=1 TO 30
1380 N$(J)="OFF" : NEXT J
1390 N$(2)="ON" : LPRINT CHR$(27);"@"; : RETURN
1400 REM THIS WILL PRINT 3 TEST LINES TO CHECK THE SETTINGS
1410 LPRINT "THIS IS A TEST LINE #1"
1420 LPRINT "TEST PATTERN FOR RX #2"
1430 LPRINT "FINAL LINE 1,2,3,4 #3" : LPRINT : LPRINT : LPRINT : LPRINT
1440 RETURN
1450 CLOSE : SYSTEM :END